Office中国论坛/Access中国论坛

标题: 在Access中应用ADO将数据输出到Word [打印本页]

作者: WTM1 时间: 2002-9-29 01:59
标题: 在Access中应用ADO将数据输出到Word
1. 系统配置
系统软件：Microsoft Windows 9x/NT/2000；Microsoft Access 2000；Microsoft Word 2000。
样例数据库：“C:\Program Files\Microsoft Office\Office\Samples\Northwind.mdb”，Office 2000中包含的例子。可将其中的“产品”表复制到一个新的数据库中，如“D:\db1.mdb”。
窗　体：在数据库“D:\db1.mdb”中新建窗体“窗体1”,其中只包含1个命令按钮“命令0”。
引用ADO：按Alt+F11进入Visual Basic编辑器，执行“工具”->“引用”命令，在弹出的引用窗体中选择“Microsoft ActiveX Data Objects 2.1”或更高版本。
引用Word：再次执行命令“工具”->“引用”，在弹出的引用窗体中选择“Microsoft Word 9.0 Object Library”。
2. 代码详解
在“窗体1”的设计模式下右键单击“命令0”按钮，选择“事件生成器”，进入Visual Basic编辑器，创建过程“Private Sub 命令0_Click()”，其代码如下：
Sub 命令0_Click()
'输入表格标题
Title = InputBox(vbCrLf & vbCrLf & "请输入表格标题：", "表格标题", "XX公司产品报价单")
If Title = "" Then Title = "XX公司产品报价单"

'步骤1：建立数据连接cnn
'由于数据库已经打开，所以直接应用CurrentProject.Connection就可以建立连接
Set cnn = New ADODB.Connection
Set cnn = CurrentProject.Connection

'步骤2：用SQL语句创建记录集rs
Set rs = New ADODB.Recordset
'设定游标类型与锁定类型
rs.CursorType = adOpenKeyset
rs.LockType = adLockOptimistic
'制定特定的查询条件，可以是任何有效的SQL查询，甚至包括多表、多条件等复杂的查询，查询条件也常常从窗体取得
SQL = "select 产品名称,单位数量,单价,库存量 from 产品 where 单价>10.00"
'创建记录集rs
rs.Open SQL, cnn
'统计字段数及记录数
total_fields = rs.Fields.Count
total_records = rs.RecordCount

'步骤3：建立Word文档对象
Set mywdapp = CreateObject("word.application")
'调整Word窗口大小
mywdapp.WindowState = wdWindowStateNormal
'生成新的Word文档实例
mywdapp.Documents.Add
'设置视图为页面视图
mywdapp.ActiveWindow.View.Type = wdPrintView
'转到Word视图，显示文档生成过程
mywdapp.Visible = True
mywdapp.Activate
'设置文档(表格)字体
mywdapp.ActiveDocument.Range.Font.Size = "9"

'步骤4：将记录集rs中的字段名称和字段内容输出到Word，各字段之间用制表符分隔
'输出字段名称
For I = 0 To total_fields - 2
mywdapp.Selection.TypeText Text:=rs.Fields(I).Name & vbTab
Next I
'最后一个字段名称后加回车符
mywdapp.Selection.TypeText Text:=rs.Fields(total_fields - 1).Name & vbCrLf
'逐条输出字段内容
Do While Not rs.EOF
For I = 0 To total_fields - 2
tmpstr = rs.Fields(I).Value
If rs.Fields(I).Name = "单价" Then
tmpstr = Format(tmpstr, "####.00")
End If
mywdapp.Selection.TypeText Text:=tmpstr & vbTab
Next I
'一条记录的最后一个字段后加回车符
mywdapp.Selection.TypeText Text:=rs.Fields(total_fields - 1).Value & vbCrLf
rs.MoveNext
Loop

'步骤5：关闭记录集
rs.Close
Set rs = Nothing

'步骤6：对Word中的数据进行格式化处理
'选定文本，将其转换为表格
'设置视图为普通视图
mywdapp.ActiveWindow.View.Type = wdNormalView
'将光标移动到文档末尾
mywdapp.Selection.EndKey Unit:=wdStory
'删除文档末尾多余的回车符
mywdapp.Selection.Delete Unit:=wdCharacter, Count:=1
'选中全部内容
mywdapp.Selection.WholeStory
'将所选内容转换为表格
mywdapp.Selection.ConvertToTable Separator:=wdSeparateByTabs, DefaultTableBehavior:=wdWord8TableBehavior
'将光标移动到文档开头
mywdapp.Selection.HomeKey Unit:=wdStory
'选定表格对象
Set Temp_Table = mywdapp.ActiveDocument.Tables(1)
'根据需要对表格进行处理，这是制作表格格式的关键，可反复调试
'本例只简单地设置了表格居中、自动调整表格列宽、表头居中、标题行重复、设置表格边框线、设置表格纵向居中
Temp_Table.Rows.Alignment = wdAlignRowCenter
Temp_Table.AutoFitBehavior wdAutoFitContent
Temp_Table.Rows(1).Range.ParagraphFormat.Alignment = wdAlignParagraphCenter
Temp_Table.Rows(1).Range.Rows.HeadingFormat = wdToggle
Temp_Table.Borders(wdBorderLeft).LineWidth = wdLineWidth150pt
Temp_Table.Borders(wdBorderRight).LineWidth = wdLineWidth150pt
Temp_Table.Borders(wdBorderTop).LineWidth = wdLineWidth150pt
Temp_Table.Borders(wdBorderBottom).LineWidth = wdLineWidth150pt
Temp_Table.Range.Cells.VerticalAlignment = wdCellAlignVerticalCenter
'将光标移动到文档开头
mywdapp.Selection.HomeKey Uni

作者: cnwang 时间: 2003-6-3 04:57
详、细。

作者: Action 时间: 2003-6-3 15:46
收藏。

作者: 李寻欢 时间: 2003-6-3 16:49
精品

作者: winak 时间: 2003-6-3 21:29
Very Good
thank you

作者: yodong 时间: 2003-6-10 20:23
WTM1朋友，能不能再来一篇输出到EXceL的例子。

作者: susanyjj 时间: 2003-6-12 21:09
我也渴望有一篇输出到EXCEL的例子噢! THANK YOU!

作者: cg1 时间: 2003-6-13 19:13
以下是各种输出数据到Excel的方法，多种多样，各有特色
http://a9.shtip.com.cn/index.asp?board=4&mode=3&recordid=74FAB41E1ADC
http://a9.shtip.com.cn/index.asp?board=4&mode=3&recordid=74FAB31E14DC
http://a9.shtip.com.cn/index.asp?board=4&mode=3&recordid=72FABF1E15DC
http://a9.shtip.com.cn/index.asp?board=4&mode=3&recordid=73FAB41E14DC

以下是两种输出数据到 Word 的方法，各有优点
http://a9.shtip.com.cn/index.asp?board=4&mode=3&recordid=73FABF1E16DC

欢迎光临 Office中国论坛/Access中国论坛 (http://www.office-cn.net/)