Office中国论坛/Access中国论坛

标题: 禁用shift代码不能运行 [打印本页]

作者: rcylbx 时间: 2007-10-17 14:31
标题: 禁用shift代码不能运行
为了禁用shift，按照斑竹"专家门诊-access开发答疑200问"中第54问的代码，可是不能运行提示
“运行时错误3270，找不到属性”

作者: andymark 时间: 2007-10-17 15:54
缺少引用吧

作者: lsqian 时间: 2007-10-17 17:24
我也遇到搂主的问题，不知道如何解决，请赐教！！！！！！！！！！！！

作者: kshtydyang 时间: 2007-10-17 19:56
标题: 可以解决shift这个问题,试试吧
Sub addshift()
  On Error GoTo ki
  If MsgBox("是否真的要取消shift键？", vbYesNo, "提示") = vbYes Then
  Set prp = CurrentDb.CreateProperty("allowbypasskey", dbBoolean, False)
  CurrentDb.Properties.Append prp
  End If
  Exit Sub
ki:
  CurrentDb.Properties("allowbypasskey") = False
End Sub

请调用这段过程就行了,不要忘记备份...

作者: WDLRCZT 时间: 2007-10-17 21:15
以下代码就是禁用和启用Shift键的函数

'禁用或启用SHIFT键
Function SetBypassProperty(Allow As Boolean)

Const DB_Boolean As Long = 1

If Allow = True Then
      ChangeProperty "AllowBypassKey", DB_Boolean, True
      MsgBox "启用Shift键设置成功！", vbInformation
Else
      ChangeProperty "AllowBypassKey", DB_Boolean, False
      MsgBox "禁用Shift键设置成功！", vbInformation
End If

End Function

Function ChangeProperty(strPropName As String, varPropType As Variant, varPropValue As Variant) As Integer
Dim DBS As Object, prp As Variant
Const conPropNotFoundError = 3270

Set DBS = CurrentDb
On Error GoTo Change_Err
DBS.Properties(strPropName) = varPropValue
ChangeProperty = True

'Dim i As Long
'For i = 1 To dbs.Properties.Count - 1
      'Debug.Print dbs.Properties(i).Name

'Next i

Change_Bye:
Exit Function

Change_Err:
If Err = conPropNotFoundError Then ' Property not found.
      Set prp = DBS.CreateProperty(strPropName, _
         varPropType, varPropValue)
      DBS.Properties.Append prp
      Resume Next
Else
      ' Unknown error.
      ChangeProperty = False
      Resume Change_Bye
End If
End Function

作者: WDLRCZT 时间: 2007-10-17 21:17
设置方法：
1）启用 SetBypassProperty True
2）禁用 SetBypassProperty False

作者: poly 时间: 2007-10-17 22:39

我太笨了，看不懂

作者: sblisb 时间: 2007-10-17 23:26
如果在窗体做一个复选框来选择,当窗体载入时,如何获得当前是否禁用shift状态?

欢迎光临 Office中国论坛/Access中国论坛 (http://www.office-cn.net/)