Office中国论坛/Access中国论坛

标题: 怎样自动引用DLL？ [打印本页]

---

作者: fatmingli    时间: 2003-6-2 19:42
标题: 怎样自动引用DLL？
怎样自动引用D：\单位程序\asd.dll 呢？

---

作者: zhengjialon    时间: 2003-6-2 20:27
若要试用该示例，请先新建一个类模块，方法是：单击“插入”菜单中的“类模块”，然后将下列代码粘贴到类模块中，并将模块保存为 RefEvents：

' Declare object variable to represent References collection.
Public WithEvents evtReferences As References

' When instance of class is created, initialize evtReferences
' variable.
Private Sub Class_Initialize()
    Set evtReferences = Application.References
End Sub

' When instance is removed, set evtReferences to Nothing.
Private Sub Class_Terminate()
    Set evtReferences = Nothing
End Sub

' Display message when reference is added.
Private Sub evtReferences_ItemAdded(ByVal Reference As _
        Access.Reference)
    MsgBox "Reference to " & Reference.Name & " added."
End Sub

' Display message when reference is removed.
Private Sub evtReferences_ItemRemoved(ByVal Reference As _
        Access.Reference)
    MsgBox "Reference to " & Reference.Name & " removed."
End Sub
以下的 Function 过程可用来添加一个特定的引用。在添加引用时，将执行 RefEvents 类中定义的 ItemAdded 事件过程。

例如，若要将引用设为日历控件，可以传递“C:\Windows\System\Mscal.ocx”字符串（只要该字符串是日历控件在计算机上的正确位置）。

' Create new instance of RefEvents class.
Dim objRefEvents As New RefEvents

' Pass file name and path of type library to this procedure.
Function AddReference(strFileName As String) As Boolean
    Dim ref As Reference

    On Error GoTo Error_AddReference
    ' Create new reference on References object variable.
    Set ref = objRefEvents.evtReferences.AddFromFile(strFileName)
    AddReference = True

Exit_AddReference:
    Exit Function

Error_AddReference:
    MsgBox Err & ": " & Err.Description
    AddReference = False
    Resume Exit_AddReference
End Function

---

作者: cg1    时间: 2003-6-2 22:27
能否这样说:"归根结底就是AddFromFile方法"？

那么mde是否能行那？

---

作者: fatmingli    时间: 2003-6-3 01:23

例如，若要将引用设为日历控件，可以传递“C:\Windows\System\Mscal.ocx”字符串（只要该字符串是日历控件在计算机上的正确位置）。

我想问怎样在打开窗体时自动引用D：\单位程序\asd.dll ，谢谢！

---

作者: Action    时间: 2003-6-3 01:26
加载事件过程中写。

---

作者: sunredday    时间: 2003-6-3 05:47
On Error Resume Next
Dim REF As Reference
Dim strfilename As String
strfilename = "c:\program files\common files\system\ado\msado21.tlb" '路径由引用窗体获得
Set REF = Application.references.AddFromFile(strfilename) '必须加APPLICATION
MsgBox REF.Name & "已经被引用完毕" '获得应用名称的途径

---

作者: sunredday    时间: 2003-6-3 05:49
On Error Resume Next
Dim REFE As Reference
Set REFE = Application.references!ADODB '由 添加时的REF.NAME获得
Dim REF As String
REF = REFE.Name
  Application.references.Remove REFE '必须加APPLICATION
   MsgBox REF & "已经被取消引用" '获得应用名称的途径

---

作者: fatmingli    时间: 2003-6-3 16:19
谢谢，方法简单一点好

---

作者: ail    时间: 2003-7-15 05:48
On Error Resume Next
Dim REFE As Reference
Set REFE = Application.references!ADODB '由 添加时的REF.NAME获得
Dim REF As String
REF = REFE.Name
  Application.references.Remove REFE '必须加APPLICATION
   MsgBox REF & "已经被取消引用" '获得应用名称的途径
是不是在登录窗体的加载事件中写入可以自动引用DLL呢？

---

欢迎光临 Office中国论坛/Access中国论坛 (http://www.office-cn.net/)

Powered by Discuz! X3.3