[求助]去除 参数查询 的提示框(已经搞定了，可以看看)

wang1999

我建立了一个参数查询，包含两个参数，如下

between [请输入起始日期值] and [请输入截止日期值] ，运行时候就会提示你输入相应数据。

我想去除这个对话框，在VBA代码中用变量赋予其参数值，

注意：我这里不能直接引用窗体的控件值，而需要用变量值输入其参数值

望大家帮帮我!

[此贴子已经被作者于2004-11-3 14:06:33编辑过]

hehang1982

你到参数菜单里把他删了不就行了吗？

wang1999

首先谢谢老弟的热心，不过你可能没有看清我的问题--参数查询去掉参数，还叫参数查询吗？

wang1999

花了4小时25分，在漫长的搜索找到一点线索，终于搞定了，(可以说把整个国内的ACCESS网站都查了一下，要命呀)，为避免大家少走弯路，我贴了出来

代码如下，(为了以避免引用DAO，所有句子有点长)

    Application.DBEngine.Workspaces(0).Databases(0).QueryDefs("Q_产品类别销售出库统计").Parameters("开始日期") = #5/21/2004#

    Application.DBEngine.Workspaces(0).Databases(0).QueryDefs("Q_产品类别销售出库统计").Parameters("结束日期") = #11/1/2004#

    Set Me.Recordset = Application.DBEngine.Workspaces(0).Databases(0).QueryDefs("Q_产品类别销售出库统计").OpenRecordset()

[此贴子已经被作者于2004-11-3 13:58:51编辑过]

wang1999

稍微改了一下，提升速度，减少垃圾Private Sub Command4_Click()

    With Application.DBEngine.Workspaces(0).Databases(0).QueryDefs("Q_产品类别销售出库统计")

        .Parameters("开始日期") = #5/21/2004#

        .Parameters("结束日期") = #11/1/2004#

        Set Me.Recordset = .OpenRecordset()

    End With

End Sub

wang1999

'ADO 的代码如下,我早就写了出来,但ACCESS窗体的记录集是DAO的,所以用ADO代码写的无法实现窗体邦定,大家也看出来,我的DAO水平也是非常差水呀    Dim cmd As New ADODB.Command, prm1 As New ADODB.Parameter, prm2 As New ADODB.Parameter, rst As ADODB.Recordset

   

    cmd.CommandText = "Q_产品类别销售出库统计"

    cmd.CommandType = adCmdStoredProc

   

    Set prm1 = cmd.CreateParameter("开始日期", adDBDate, adParamInput)

    cmd.Parameters.Append prm1

    prm1.Value = #10/1/2004#

   

    Set prm2 = cmd.CreateParameter("结束日期", adDBDate, adParamInput)

    cmd.Parameters.Append prm2

    prm2.Value = #11/1/2004#

   

    Set cmd.ActiveConnection = CurrentProject.Connection

    Set rst = cmd.Execute'这个问题在去年就困扰着我，今天搞定了，真的叫爽呀

wang1999

原来还可以直接用    CurrentDb 方法 来引用With CurrentDb.QueryDefs("Q_产品类别销售出库统计")

        .Parameters("开始日期") = #5/21/2004#

        .Parameters("结束日期") = #11/1/2004#

        Set Me.Recordset = .OpenRecordset()

    End With