如何在VBA判断EXCEL或WORD文件已经打开，并用代码关闭

huanghai

如何在VBA（ACCESS）中用代码判断一个EXCEL或WORD文件已经打开，并用代码关闭

竹笛

笨办法，你试试：
1、在ACCESS代码中获取那个EXCEL文件中一个指定的cells的value
2、如果出错……，您知道了吧。
3、关闭这个EXCEL：
olxApp.Quit
Set olxApp = Nothing '这个你是知道的

李寻欢

Dim MyXL As Object
    Set MyXL = GetObject(, "Excel.Application")
    For Each axls In MyXL.workbooks
        If InStr(1, axls.Name, "book1.xls", 1) Then
            'axls.Close     '关闭文档
            MyXL.Quit    '退出excel
            Exit For
        End If
    Next axls
    Set MyXL = Nothing

[此贴子已经被作者于2003-6-17 22:20:35编辑过]

eio

嘿，如果打开EXECL程序，其默认“book1”，上述程序就无能为力了。

李寻欢

干嘛不试一试再发言

eio

试过了,我不是莽语的.

marco2

EIO，你试的是不正确的，因为可以将“book1.xls”改为默认打开的“book1”即可，这时依然可以找到工作簿。
但寻欢，这个问题你试过没有？当打开两个Excel.application，而你要查找的对象却在第二个工程里时，你提供的方法却无能为力了！
不过你的方法还是非常棒的，至少已经搞定了一半，而且是纯VBA实现的！：）

huanghai

谢谢寻欢，原来核心就是GETOBJECT，特帖帮助内容，与大家分享：

GetObject 函数示例
该示例使用 GetObject 函数来获取对指定的 Microsoft Excel 的工作表 (MyXL) 的引用。它使用工作表的 Application 属性来显示或关闭 Microsoft Excel 等等。DetectExcel Sub 过程通过调用两个 API 函数，来查找 Microsoft Excel。如果 Microsoft Excel 正在运行，则将其放入运行对象表（Running Object Table）中。如果 Microsoft Excel 不在运行，则第一次调用 GetObject 将导致错误。在本例中，出现该错误则把 ExcelWasNotRunning 标志设为 True。第二次调用 GetObject 是指定要打开的一个文件。如果 Microsoft Excel 不在运行，则这个第二次的调用将启动该程序，并返回一个指定文件 (mytest.xls) 所对应的工作表的引用。该文件必须位于指定的位置；否则将产生 Visual Basic 错误及自动化错误。随后的示例代码将 Microsoft Excel 及包含指定工作表的窗口设为可见。最后，如果在此前没有 Microsoft Excel 的副本在运行，代码就使用 Application 对象的 Quit 方法来关闭 Microsoft Excel。如果该应用程序原来就在运行，则不要试图关闭它。引用本身在设为 Nothing 后被释放。

'声明必要的 API 例程：
Declare Function FindWindow Lib "user32" Alias _
"FindWindowA" (ByVal lpClassName as String, _
                    ByVal lpWindowName As Long) As Long

Declare Function SendMessage Lib "user32" Alias _
"SendMessageA" (ByVal hWnd as Long,ByVal wMsg as Long _
                    ByVal wParam as Long, _
                    ByVal lParam As Long) As Long

Sub GetExcel()
    Dim MyXL As Object    '用于存放
                                'Microsoft Excel 引用的变量。
    Dim ExcelWasNotRunning As Boolean    '用于最后释放的标记。

'测试 Microsoft Excel 的副本是否在运行。
    On Error Resume Next    '延迟错误捕获。
'不带第一个参数调用 Getobject 函数将
'返回对该应用程序的实例的引用。
'如果该应用程序不在运行，则会产生错误。
    Set MyXL = Getobject(, "Excel.Application")
    If Err.Number <> 0 Then ExcelWasNotRunning = True
    Err.Clear    '如果发生错误则要清除 Err 对象。

'检测 Microsoft Excel。如果 Microsoft Excel 在运行，
'则将其加入运行对象表。
    DetectExcel

'将对象变量设为对要看的文件的引用。
    Set MyXL = Getobject("c:\vb4\MYTEST.XLS")

'设置其 Application 属性，显示 Microsoft Excel。
'然后使用 MyXL 对象引用的 Windows 集合
'显示包含该文件的实际窗口。
    MyXL.Application.Visible = True
    MyXL.Parent.Windows(1).Visible = True
    '在此处对文件
    '进行操作。
    ' ...
'如果在启动时，Microsoft Excel 的这份副本不在运行中，
'则使用 Application 属性的 Quit 方法来关闭它。
'注意，当试图退出 Microsoft Excel 时，
'标题栏会闪烁，并显示一条消息
'询问是否保存所加载的文件。
    If ExcelWasNotRunning = True Then
        MyXL.Application.Quit
    End IF

    Set MyXL = Nothing    '释放对该应用程序
                                '和电子数据表的引用。
End Sub

Sub DetectExcel()
'该过程检测并登记正在运行的 Excel。
    Const WM_USER = 1024
    Dim hWnd As Long
'如果 Excel 在运行，则该 API 调用将返回其句柄。
    hWnd = FindWindow("XLMAIN", 0)
    If hWnd = 0 Then    '0 表示没有 Excel 在运行。
        Exit Sub
    Else               
    'Excel 在运行，因此可以使用 SendMessage API
    '函数将其放入运行对象表。
        SendMessage hWnd, WM_USER + 18, 0, 0
    End If
End Sub

huanghai

寻欢兄，检查一下学习成果：）

'功能：
'判断EXCEL文件是否打开并关闭
'使用方法例：
'checkXlsFileOpenAndClose ("book1.xls")

Public Function checkXlsFileOpenAndClose(ByVal strXlsFileName As String)

    On Error Resume Next
    Dim MyXL As Object
    Dim axls As Object
    Set MyXL = GetObject(, "Excel.Application")
    If Err.Number <> 0 Then Exit Function
    For Each axls In MyXL.workbooks
        'If InStr(1, axls.Name, strXlsFileName, 1) Then
        If axls.Name = strXlsFileName Then
            axls.Close     '关闭文档
            ' MyXL.Quit    '退出excel
            Exit For
        End If
    Next axls
    Set axls = Nothing
    Set MyXL = Nothing

End Function

huanghai

eio，看看我试的寻欢的代码，找找你的原因。