Show 一个没有菜单的界面(ADP)

zhuyiwen

界面导航元素：选项卡、子窗体、按钮

(注：照片的存储格式为直接的JPG文件存储在image字段，显示采用MSFORM2.0.Image控件，非ACCESS的Image和绑定对象控件, 这样的好处是占用空间小。)

请大家评评。

zhufree

好早呀

t小宝

界面布置紧凑合理，赞！
照片显示采用MSFORM2.0.Image控件，是否还要释放临时图片文件？

zhuyiwen

t小宝 发表于 2011-7-19 10:01
界面布置紧凑合理，赞！
照片显示采用MSFORM2.0.Image控件，是否还要释放临时图片文件？

不用产生临时文件，直接读字段内容。
注：MSFORM2.0为Office自带控件，通常用于UserForm(用户窗体)。

chaosheng

漂亮啊,学习.

zhuyiwen

贴一段读图片的代码：

1. Option Compare Database
   
2. Option Explicit
   
3. 
   
4. Private Const S_OK = 0    ' indicates successful HRESULT
   
5. Private Const sIID_IPicture = "{7BF80980-BF32-101A-8BBB-00AA00300CAB}"
   
6. Private Const GMEM_MOVEABLE = &H2
   
7. 
   
8. Private Type GUID    ' 16 bytes (128 bits)
   
9.   dwData1 As Long    ' 4 bytes
   
10.   wData2 As Integer  ' 2 bytes
    
11.   wData3 As Integer  ' 2 bytes
    
12.   abData4(7) As Byte ' 8 bytes, zero based
    
13. End Type
    
14. 
    
15. Public Enum CBoolean   ' enum members are Long data types
    
16.   CFalse = 0
    
17.   CTrue = 1
    
18. End Enum
    
19. 
    
20. Private Declare Function GlobalAlloc Lib "kernel32" (ByVal uFlags As Long, ByVal dwBytes As Long) As Long
    
21. Private Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) As Long
    
22. Private Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) As Long
    
23. Private Declare Function GlobalFree Lib "kernel32" (ByVal hMem As Long) As Long
    
24. 
    
25. Private Declare Function CLSIDFromString Lib "ole32" (ByVal lpsz As Any, pCLSID As GUID) As Long
    
26. Private Declare Function OleLoadPicture Lib "olepro32" (pStream As Any, ByVal lSize As Long, ByVal fRunmode As CBoolean, riid As GUID, ppvObj As Any) As Long
    
27. 
    
28. Private Declare Function CreateStreamOnHGlobal Lib "ole32" (ByVal hGlobal As Long, ByVal fDeleteOnRelease As CBoolean, ppstm As Any) As Long
    
29. 
    
30. Private Declare Sub MoveMemory Lib "kernel32" Alias "RtlMoveMemory" (pDest As Any, pSource As Any, ByVal dwLength As Long)
    
31. 
    
32. 
    
33. Public Function PictureFromBits(abPic() As Byte) As IPicture  ' not a StdPicture!!
    
34.     Dim nLow As Long, cbMem  As Long, hMem  As Long
    
35.     Dim lpMem  As Long, IID_IPicture As GUID
    
36.     Dim IStm As stdole.IUnknown, IPic As IPicture
    
37.     ' Get the size of the picture's bits
    
38.     On Error GoTo Out
    
39.     nLow = LBound(abPic)
    
40.     On Error GoTo 0
    
41.     cbMem = (UBound(abPic) - nLow) + 1
    
42.     ' Allocate a global memory object
    
43.     hMem = GlobalAlloc(GMEM_MOVEABLE, cbMem)
    
44.     If hMem Then
    
45.         ' Lock the memory object and get a pointer to it.
    
46.         lpMem = GlobalLock(hMem)
    
47.         If lpMem Then
    
48.             ' Copy the picture file bytes to the memory pointer
    
49.             ' and unlock the handle.
    
50.             MoveMemory ByVal lpMem, abPic(nLow), cbMem
    
51.             Call GlobalUnlock(hMem)
    
52.             ' Create an ISteam from the pictures bits (we can
    
53.             ' explicitly free hMem below, but we'll have the
    
54.             ' call do it here...)
    
55.             If (CreateStreamOnHGlobal(hMem, CTrue, IStm) = S_OK) Then
    
56.                 If (CLSIDFromString(StrPtr(sIID_IPicture), _
    
57.                     IID_IPicture) = S_OK) Then
    
58.                     ' Create an IPicture from the IStream (the docs
    
59.                     ' say the call does not AddRef its last param, but
    
60.                     'it looks like the reference counts are correct..)
    
61.                     Call OleLoadPicture(ByVal ObjPtr(IStm), cbMem, CFalse, IID_IPicture, PictureFromBits)
    
62.                 End If   ' CLSIDFromString
    
63.             End If   ' CreateStreamOnHGlobal
    
64.         End If   ' lpMem
    
65.         Call GlobalFree(hMem)
    
66.     End If   ' hMem
    
67. Out:
    
68. End Function
    
69. 
    
70. 
    
71. 'With Form Inet1 Control
    
72. 'Private Function GetPicFromHTTP(strURL As String, Optional Username As String, Optional Password As String) As IPicture
    
73. '    Dim bytearray() As Byte
    
74. '
    
75. '    Inet1.URL = strURL
    
76. '    Inet1.Username = Username
    
77. '    Inet1.Password = Password
    
78. '    bytearray() = Inet1.OpenURL(, icByteArray)
    
79. '
    
80. '    Set GetPicFromHTTP = PictureFromBits(bytearray)
    
81. '
    
82. 'End Function
    
83. 
    
84. 
    
85. '
    
86. 'Private Sub Command1_Click()
    
87. '    Picture1.Picture = GetPicFromHTTP("http://msdn.microsoft.com/library/shared/toolbar/graphics/banners/MSDN_banner.gif";) '("http://www.wandtv.com/rdrimg.jpg";)
    
88. 'End Sub
    
89. 
    
90. 
    
91. Public Function LoadPictureFromField(f As ADODB.field) As StdPicture
    
92.     Dim b1() As Byte
    
93.    
    
94.     If f.ActualSize <> 0 Then
    
95.         ReDim b1(1 To f.ActualSize) As Byte
    
96.         b1 = f.GetChunk(f.ActualSize)
    
97.         Set LoadPictureFromField = PictureFromBits(b1)
    
98.     End If
    
99. End Function
    
100. 
     
101. 
     
102. Public Function LoadPictureFromFile(filePath As String) As StdPicture
     
103.     Dim b1() As Byte
     
104.    
     
105.     Open filePath For Binary As #1
     
106.     ReDim b1(1 To LOF(1))
     
107.     Get 1, , b1
     
108.     Close 1
     
109.    
     
110.     Set LoadPictureFromFile = PictureFromBits(b1)
     
111. End Function
     

复制代码

zhuyiwen

调用Public Function LoadPictureFromField(f As ADODB.field) As StdPicture函数从字段读图片到MSFORM20.Image控件。当然，这个Field可以是SQL Server的Image字段，也可以是mdb的OLE字段，关键是这个字段存储的图片的内容，而非OLE对象。

yanwei82123300

老师就是厉害！！

t小宝

回复 zhuyiwen 的帖子

朱总的代码好呀，我也曾用了类似的方法。
其实jpg图片数据也可用代码转换后，在ACCESS.image控件显示。

zhuyiwen

t小宝 发表于 2011-7-19 12:56


朱总的代码好呀，我也曾用了类似的方法。其实jpg图片数据也可用代码转换后，在ACCESS.image控件显示。

能否共享一下？