对两个表进行处理的一段半角替换全角代码能否简化

wang1950317

红色部分是andymark老师提供的用半角替换全角的代码，用于对表1中“结果”列误按全角输入的数字替换成半角数字，现在把它用于处理两个表，即表1表2，运行没有问题，但请教各位老师，这段代码可否简化？谢谢！

Private Sub 半角替换全角_Click()
Dim Rs As New ADODB.Recordset
Dim Conn As New ADODB.Connection
Dim Str As String
Set Conn = CurrentProject.Connection

Rs.Open "select * from 表1", Conn, adOpenDynamic, adLockOptimistic
Do While Not Rs.EOF
Str = Rs.Fields("结果")
If Asc(Str) < 0 Then
   Str = Replace(Str, "。", ".")
   Str = StrConv(Str, vbNarrow)
  Rs.Fields("结果") = Str
  Rs.Update
End If
  
Rs.MoveNext

Loop

Rs.Close

Set Rs = Nothing
Set Conn = Nothing

Set Conn = CurrentProject.Connection

Rs.Open "select * from 表2", Conn, adOpenDynamic, adLockOptimistic
Do While Not Rs.EOF
Str = Rs.Fields("结果")
If Asc(Str) < 0 Then
   Str = Replace(Str, "。", ".")
   Str = StrConv(Str, vbNarrow)
  Rs.Fields("结果") = Str
  Rs.Update
End If
  
Rs.MoveNext

Loop

Rs.Close

Set Rs = Nothing
Set Conn = Nothing

   
End Sub

hi-wzj

可提炼成过程（参数为表名称和字段名称）
事件中调用该过程。

wang1950317

谢谢hi-wzj版主，您的意思是做成自定义函数吗？其实这段代码只用一至两次，我是看到这两段大部分重复，就想请教一下能否合并简化。能与不能简化对学习代码都是非常有用的知识积累。谢谢！
另外，输入数字如这样的格式：<０．２５（<号是半角而0.25是全角的）代码就不起作用了。好在输入数据时一段数字既按全角又按半角输入的几率少之又少。可以不去管它了。

[ 本帖最后由 wang1950317 于 2007-10-19 11:12 编辑 ]

fan0217

先定义一个半角替换全角的函数（参数为被替换的文本和替换为文本），然后再替换表中字段值的函数（参数为表名称和字段名称），在替换时调用前面定义的半角替换全角的函数。

一个函数最好只完成一个简单的功能。

wang1950317

谢谢fan0217老师指教。我的理解是基于这段代码本身两位版主的意见是不能再做简化的了，必须使用另外的方法。谢谢啦！按你们的方法做做看。

[ 本帖最后由 wang1950317 于 2007-10-19 14:04 编辑 ]

andymark

Private Sub 半角替换全角_Click()
Call QJ2BJ("表1", "结果")
Call QJ2BJ("表2", "结果")
End Sub

Sub QJ2BJ(StrTableName As String, StrFildName As String)

Dim Rs As New ADODB.Recordset
Dim Conn As New ADODB.Connection
Dim Str As String
Set Conn = CurrentProject.Connection

Rs.Open "select * from " & StrTableName & "", Conn, adOpenDynamic, adLockOptimistic

Do While Not Rs.EOF
   Str = Rs.Fields("" & StrFildName & "")
   Str = StrConv(Str, vbWide)                           ' 为防止全角半角的混合输入,统一转换为全角
   Str = Replace(Str, "。", ".")
   Str = Replace(Str, "．", ".")
   Str = StrConv(Str, vbNarrow)
   Rs.Fields("" & StrFildName & "") = Str
   Rs.Update

    Rs.MoveNext

Loop

Rs.Close

Set Rs = Nothing
Set Conn = Nothing

End Sub

wang1950317

可以简化了。对全角半角混输问题，非常崇拜andymark老师的不管是对的还是错的，先把它统一改成为错的，然后再将错的纠正过来的思路！