关于inputbox输入星号引起的疑问，高手请！特别是tanhong

xryacc2

参阅了tanhong 的一个作品，感觉很好，但突然有一个疑问，就是在同一个过程中，要用到两次inpubbox，一次是要用到星号，另一次不要用到星号，请问在这种情况下，tanhong 作品中的代码写法是否会引起程序不稳？（试过好像没发现明显问题，但总有这样的疑惑），期待高手解答，如果tanhong 本人看到给予解答就更好了。（有附件，tanhong 的这个附件是开放源代码的。）谢谢。

红尘如烟

不存在你说的问题，它这个大致是先创建一个计时器，打开InputBox对话框后，在计时器触发事件中将对话框输入设为星号掩码
你说的一个有星号是因为创建了计时器，一个没有星号是没有创建计时器，两者没有什么关联影响
可以按照这个思路把InputBox函数扩展一下改成InputBoxEx，增加一个Asterisk参数，表示是否将输入框中输入的内容显示为星号，代码如下：

1. Option Explicit
   
2. Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
   
3. Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
   
4. Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
   
5. Private Declare Function timeSetEvent Lib "winmm.dll" (ByVal uDelay As Long, ByVal uResolution As Long, ByVal lpFunction As Long, ByVal dwUser As Long, ByVal uFlags As Long) As Long
   
6. Private Declare Function timeKillEvent Lib "winmm.dll" (ByVal uID As Long) As Long
   
7. Private m_lTimeID As Long
   
8. Private m_InputBoxTitle As String
   
9. Private m_PasswordMask As Boolean
   
10. 
    
11. Public Sub TimeProc(ByVal uID As Long, ByVal uMsg As Long, ByVal dwUser As Long, ByVal dw1 As Long, ByVal dw2 As Long)
    
12. On Error Resume Next
    
13.     Dim hwnd As Long
    
14.     Dim wMsg As Long
    
15.    
    
16.     hwnd = FindWindow("#32770", m_InputBoxTitle)
    
17.     If hwnd <> 0 Then
    
18.         hwnd = FindWindowEx(hwnd, 0, "EDIT", vbNullString)
    
19.         wMsg = IIf(m_PasswordMask, &HCC, 0)
    
20.         SendMessage hwnd, wMsg, 42, 0
    
21.         timeKillEvent m_lTimeID
    
22.     End If
    
23. End Sub
    
24. 
    
25. 'InputBox函数扩展，增加了是否以星号显示输入内容
    
26. '扩展Asterisk参数：是否将输入的内容显示为星号，默认为否（false）,其它参数和InputBox函数的参数相同
    
27. 
    
28. Public Function InputBoxEx(Prompt, Optional Title, Optional Asterisk As Boolean = False, Optional Default, _
    
29.                            Optional XPos, Optional YPos, Optional HelpFile, Optional Context) As String
    
30. On Error Resume Next
    
31.    
    
32.     m_PasswordMask = Asterisk
    
33.     If IsMissing(Title) Then Title = Space(16)
    
34.     m_InputBoxTitle = Title
    
35.     m_lTimeID = timeSetEvent(10, 0, AddressOf TimeProc, 1, 1)
    
36.     InputBoxEx = InputBox(Prompt, Title, Default, XPos, YPos, HelpFile, Context)
    
37.    
    
38. End Function
    

复制代码

xryacc2

非常感谢“红尘如烟”！