有关ADP禁止SHIFT键的方法

tmtony

Function DisableBypassADP(blnYesNo As Boolean)
    CurrentProject.Properties.Add "AllowByPassKey", blnYesNo
End Function

然后在启动时调用 DisableBypassADP(false)

更详细的做法:

Function SetMyProperty(MyPropName As String, MyPropValue As Variant) As Boolean
    On Error GoTo SetMyProperty_In_Err
    Dim Ix As Integer
    With CurrentProject.Properties
    If fn_PropertyExist(MyPropName) Then  'check if it already exists
        For Ix = 0 To .Count - 1
            If .Item(Ix).Name = MyPropName Then
                .Item(Ix).Value = MyPropValue
            End If
        Next Ix
    Else
       .Add MyPropName, MyPropValue
    End If
    End With
    SetMyProperty = True

SetMyProperty_Exit:
    Exit Function

SetMyProperty_In_Err:
   
    MsgBox "设置属性出错:", Err, Error$
    SetMyProperty = False
    Resume SetMyProperty_Exit

End Function
'--------检查属性是否存在---
Private Function fn_PropertyExist(MyPropName As String) As Boolean
    fn_PropertyExist = False
    Dim Ix As Integer
    With CurrentProject.Properties
        For Ix = 0 To .Count - 1
            If .Item(Ix).Name = MyPropName Then
                fn_PropertyExist = True
                Exit For
            End If
        Next Ix
    End With
End Function


Public Function setByPass()
   SetMyProperty "AllowBypassKey", True
End Function

huanghai

好,收到。

cg1

AllowBypassKey 属性
请参阅 示例 特性使用 AllowBypassKey 属性可以指定是否允许用 Shift 键来忽略启动属性和 AutoExec 宏。例如，将 AllowBypassKey 属性设为 False 可避免用户忽略启动属性和 AutoExec 宏。

设置
AllowBypassKey 属性使用以下设置：

设置 说明
True 允许用户使用 Shift 忽略启动属性和 AutoExec 宏。
False 禁止用户使用 Shift 忽略启动属性和 AutoExec 宏。


可以使用宏或者 Visual Basic 设置该属性。

若要使用宏或 Visual Basic 设置 AllowBypassKey 属性，必须使用以下方法创建该属性：

在 Microsoft Access 数据库 (.mdb) 中，可以通过使用 CreateProperty 方法添加该属性，并将其追加到 Database 对象的 Properties 集合中。
注意这里：
在 Microsoft Access 项目 (.adp) 中，可以通过使用 Add 方法将该属性添加到 CurrentProject 对象的 AccessObjectProperties 集合中。
说明
调试应用程序时,应确保 AllowBypassKey 属性设为 True。

该属性的设置仅在下一次打开应用程序数据库时才会生效。

示例
下面的示例显示了一个名为 SetBypassProperty 的过程，该过程传递要设置的属性的名称、数据类型及所需设置。一般用途过程 ChangeProperty 将尝试设置 AllowBypassKey 属性，如果找不到该属性，则用 CreateProperty 方法将其追加到 Properties 集合中。这是必要的步骤，因为只有在添加之后，该属性才出现在 Properties 集合中。

Sub SetBypassProperty()
Const DB_Boolean As Long = 1
    ChangeProperty "AllowBypassKey", DB_Boolean, False
    '--------------如果需要解开shift锁定可以用以下代码：
    'ChangeProperty "AllowBypassKey", DB_Boolean, true

End Sub

Function ChangeProperty(strPropName As String, varPropType As Variant, varPropValue As Variant) As Integer
    Dim dbs As Object, prp As Variant
    Const conPropNotFoundError = 3270

    Set dbs = CurrentDb
    On Error GoTo Change_Err
    dbs.Properties(strPropName) = varPropValue
    ChangeProperty = True

Change_Bye:
    Exit Function

Change_Err:
    If Err = conPropNotFoundError Then    ' Property not found.
        Set prp = dbs.CreateProperty(strPropName, _
            varPropType, varPropValue)
        dbs.Properties.Append prp
        Resume Next
    Else
        ' Unknown error.
        ChangeProperty = False
        Resume Change_Bye
    End If
End Function

tszysun

OK

GOODWIN

很好