可不可以向子窗体导入数据？

wlltnt

我把问题写在窗体上了，问的是导入的数据只做为一张订单的内容？

ADAM

可以啊,
增加一個按鈕,在CLICK中寫入
DOCMD.TransferSpreadsheet ...
'具體命令用法見幫助文件....
ME.Requery

wlltnt

如果是那样，我还是用宏好了，可是却不行，可不可以给个例子，还有一定要一张订单的内容才有用，麻烦了

ADAM

是可以的,
我做的那個BOM什么系統,之"產量錄入表單"中
有和EXCEL匯出與匯入動作的按鈕,就是這樣寫的...
其實這個功能盡量是非常適用的....
(你搜索一下'BOM'就可以找得到,論壇上關于這個的很少)

wlltnt

下载了一个，可是老出错，又看不懂

ADAM

是用繁體寫的,你只看代碼就可以了嗎..,
算了,我把代碼貼出來好了...
'輸入表單關鍵字定義
'表單子表記錄集定義
Public RECORD1 As String
'表單清空查詢
Public DELE1 As String
'表單匯出來源最新BOM編號
Public OUTPUT1 As String
'表單匯入路徑
Public INPUT_E As String

Private Sub Form_Open(Cancel As Integer)
On Error GoTo Err_資料輸入表_OPEN

DELE1 = "成品產量輸入表清空"
OUTPUT1 = "現有成品BOM代號"
INPUT_E = Filepath & "成品產量輸入表.xls"
RECORD1 = "BOM_Q"

Exit_資料輸入表_OPEN:
    Exit Sub

Err_資料輸入表_OPEN:
    MsgBox Err.Description
    Resume Exit_資料輸入表_OPEN

End Sub

Private Sub 產量清空_Click()
On Error GoTo Err_產量清空_Click

DoCmd.OpenQuery "轉換產量清零"

Exit_產量清空_Click:
    Exit Sub

Err_產量清空_Click:
    MsgBox Err.Description
    Resume Exit_產量清空_Click

End Sub

Private Sub 匯入資料_Click()
'匯入產量
On Error GoTo Err_匯入產量_Click

DoCmd.OpenQuery DELE1, acViewNormal
DoCmd.TransferSpreadsheet acImport, acSpreadsheetTypeExcel8, RECORD1, INPUT_E, True
Me.資料子表單.Form.RecordSource = RECORD1

Exit_匯入產量_Click:
    Exit Sub

Err_匯入產量_Click:
    MsgBox Err.Description
    Resume Exit_匯入產量_Click

End Sub

Private Sub 用EXCEL輸入_Click()
On Error GoTo Err_執行EXCEL_Click
Dim oApp As Object

DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel8, OUTPUT1, INPUT_E, True
   
    Set oApp = CreateObject("Excel.Application")
    oApp.Visible = True
    oApp.Application.workbooks.Open INPUT_E
      
    On Error Resume Next
    oApp.UserControl = True

Exit_執行EXCEL_Click:
    Exit Sub

Err_執行EXCEL_Click:
    MsgBox Err.Description
    Resume Exit_執行EXCEL_Click

End Sub


Private Sub 退出_Click()
On Error GoTo Err_退出_Click


    DoCmd.Close

Exit_退出_Click:
    Exit Sub

Err_退出_Click:
    MsgBox Err.Description
    Resume Exit_退出_Click
   
End Sub

唐小小

http://www.office-cn.net/bbs/dispbbs.asp?boardID=2&ID=12218
你可以试试这个哦，可以使access与excel更好的结合：）