泣血求教各位大侠:如何把access的主界面隐藏

freshcool

就是使启动时只出现自己做的窗体,而不出现access的操作界面,我在论坛上找了很久也找不到,现在急着用啊,请各位大侠帮帮忙,给个链接我自己看也行啊,5555,bow!![em00][em00]

徐阿鹏

通过一函数已定义的常量 fSetAccessWindow 实现。

该函数能用来完全隐藏 Access 窗口并将你自己的窗体显示在桌面上。在弹出式窗体的 Open 事件中使用 SW_HIDE 参数调用 fSetAccessWindow 函数实现。

注意：如果你隐藏了 Access 主窗口，要确定你有良好的出错处理。因为主窗口隐藏后，一旦引发错误，并出错提示窗口上点击了“结束”按钮，这样不会使 Access 主窗口可见，并退出你自己的窗体。推荐你在你的错误处理程序中使用 SW_SHOWNORMAL 参数调用 fSetAccessWindow 函数来显示 Access 主窗口。
如果由于别的原因，Access 主窗口不能显示，那么你将只能从任务栏中关闭你的 mdb，在 Win 9x 中使用 Control-Alt-Delete 来结束任务，在 Win NT 、2000 或 XP 中，可以右键单击任务栏选择任务管理器来选择该 mdb 结束任务。


'************ 代码开始 **********
Global Const SW_HIDE = 0
Global Const SW_SHOWNORMAL = 1
Global Const SW_SHOWMINIMIZED = 2
Global Const SW_SHOWMAXIMIZED = 3


Private Declare Function apiShowWindow Lib "user32" _
　　Alias "ShowWindow" (ByVal hwnd As Long, _
　　　　　ByVal nCmdShow As Long) As Long

Function fSetAccessWindow(nCmdShow As Long)
' 使用举例
' 最大化 Access 窗口
'　　　 ?fSetAccessWindow(SW_SHOWMAXIMIZED)
' 最小化 Access 窗口
'　　　 ?fSetAccessWindow(SW_SHOWMINIMIZED)
' 隐藏 Access 窗口
'　　　 ?fSetAccessWindow(SW_HIDE)
' 正常显示 Access 窗口
'　　　 ?fSetAccessWindow(SW_SHOWNORMAL)
'
Dim loX　As Long
Dim loFORM As FORM
　　On Error Resume Next
　　Set loFORM = Screen.ActiveFORM
　　If Err <> 0 Then ' 没有活动窗体 no ActiveFORM
　　　If nCmdShow = SW_HIDE Then
　　　　MsgBox "除非屏幕上有一个窗口，否则不能隐藏 Access 主窗口!" _
　　　　　　　　　　& vbcr & vbcr　_
　　　　　　　　　　& "Cannot hide Access unless " _
　　　　　　　　　　& "a FORM is on screen"
　　　Else
　　　　loX = apiShowWindow(hWndAccessApp, nCmdShow)
　　　　Err.Clear
　　　End If
　　Else
　　　　If nCmdShow = SW_SHOWMINIMIZED And loFORM.Modal = True Then
　　　　　　MsgBox "不能由屏幕上的 " & (loFORM.Caption + " ")　& "窗体最小化 Access 主窗口!" _
　　　　　　　　　　& vbcr & vbcr　_
　　　　　　　　　　& "Cannot minimize Access with " _
　　　　　　　　　　& (loFORM.Caption + " ") _
　　　　　　　　　　& "FORM on screen"
　　　　ElseIf nCmdShow = SW_HIDE And loFORM.PopUp <> True Then
　　　　　　MsgBox "不能由屏幕上的 " & (loFORM.Caption + " ")　& "窗体隐藏 Access 主窗口!" _
　　　　　　　　　　& vbcr & vbcr　_
　　　　　　　　　　& "Cannot hide Access with " _
　　　　　　　　　　& (loFORM.Caption + " ") _
　　　　　　　　　　& "FORM on screen"
　　　　Else
　　　　　　loX = apiShowWindow(hWndAccessApp, nCmdShow)
　　　　End If
　　End If
　　fSetAccessWindow = (loX <> 0)
End Function

'************ 代码结束 **********

freshcool

这种方法在access2002中能够使用么?我看到一个帖子说只能在97中使用啊,多谢您的指导了,徐阿鹏大侠

seaload

启动－>勾全部点掉
自己的主窗体：属性－>其它－>弹出设为是

徐阿鹏

所有的窗体都要将属性－>其它－>弹出设为是
，不然就隐藏了，打开也看不见，

freshcool

这样的话还是会出现access的菜单栏的啊

ADAM

簡單的設法:
在表單的LOAD事件中加入
DOCMD.RunCommand acCmdAppMinimize
DOCMD.RESTORE
設定窗體為:彈出式,獨占式,
這樣雖說不能達到很好的效果,但是也較簡單,

徐阿鹏

不会的啊！我试过的，你要的主窗体的open事件中调用这个函数啊

freshcool

哦,好啊,谢谢您拉,呵呵,等我搞定了再来谢您啊

佳佳

能上传个例子吗