SOAP應用介紹

2019-11-12 23:21:00
zstmtony
轉貼
136


如果想瞭解SOAP到底是什麽,就要自己動手建立自己的SOAP標準對象。本文可以幫助你起步。
============================================

簡介
SOAP - 簡單對象處理協議(Simple Object Access Protocol) - 是當前XML開髮的熱點。牠是微軟新一代Visual Studio的主要角色,是".NET"策略的基礎。如果想用VB 6編製一箇有保障的SOAP服務,可以查閲微軟的SOAP工具包(VB)。但如果想瞭解SOAP到底是什麽,就要自己動手建立自己的SOAP標準對象。本文可以幫助你起步。

本文中,我們創建一箇簡單的SOAP服務端和一箇客戶端。服務端用ASP編寫,名爲soap.asp。這箇文件應存放在箇人Web服務器的根目録下,如:/Inetpub/wwwroot。這箇服務器將接受和處理客戶端提齣的SOAP請求。客戶端是一箇簡單的VB可執行文件,由Sub Main()啟動。

步驟
衆所週知,SOAP是一箇“呼叫-響應”機製,按客戶/服務方式運行。客戶端(應用程序)曏服務端(位於互聯網上的某箇Web服務器)髮齣函數調用請求併傳遞蔘數;服務端則返迴響應。呼叫與響應的內容和數據都是按XML文件格式進行傳送的。因此,要建立一箇簡單的SOAP應用繫統,就要建立一箇客戶端和一箇服務端,卽一箇呼叫-響應體繫。

下麵是一箇簡單例子:
我們建立一箇服務端來計祘銷售交易的稅款。按照傳統的VB術語,卽建立一箇函數,定義如下:
      Public Function GetSalesTax(ByVal pSalesTotal As Double) as Double
          GetSalesTax = pSalesTotal * 0.04
      End Function

一箇粗糙的函數,但可作爲示例(本例隻能用於稅率爲4%的地方)。
這箇函數定義瞭一箇函數名(GetSalesTax),一箇蔘數(pSalesTotal – 銷售金額)和一箇返迴值(函數返迴值)。按照麵曏對象原則,可以認爲pSalesTotal是一箇"IN"蔘數,GetSalesTax返迴值是一箇"OUT"蔘數。因此我們的SOAP服務端就要偵聽客戶髮齣的調用GetSalesTax的請求和傳遞的"IN"蔘數(銷售金額),然後返迴帶有"OUT"蔘數的迴應,曏客戶返迴所需稅款。

客戶端
下麵是用VB建立一箇呼叫服務的客戶端程序:
      dblSalesTax = GetSalesTax(100)
      得到返迴值$4。
     
      如果GetSalesTax函數是一箇外部對象,比如在MTS服務器上,就要調用服務器上的DLL模塊:
      Dim objTax As New CTaxCalc
      dblSalesTax = objTax.GetSalesTax(100)

在SOAP繫統中,遠程調用的方式略有不衕,呼叫是通過XML文件傳送到服務器的。XML文件裡有調用的函數名和相應的蔘數:
      <GetSalesTax>
          <SalesTotal>100</SalesTotal>
      <GetSalesTax>

爲確保服務器能夠識彆和解釋客戶請求,呼叫指令被包裝到一箇稱之爲SOAP信封的大文件裡。這箇信封使用的是SOAP封裝標準的通用命名空間:
      <SOAP:Envelope xmlns:SOAP="urn:schemas-xmlsoap-org:soap.v1">
          <SOAP:Header></SOAP:Header>
          <SOAP:Body>
              <GetSalesTax>
                  <SalesTotal>100</SalesTotal>
              <GetSalesTax>
          </SOAP:Body>
      </SOAP:Envelope>

最後,加入函數調用的命名空間,起到函數聲明的作用:
      <SOAP:Envelope xmlns:SOAP="urn:schemas-xmlsoap-org:soap.v1">
          <SOAP:Header></SOAP:Header>
          <SOAP:Body>
              <m:GetSalesTax xmlns:m="urn:myserver/soap:TaxCalc">
                  <SalesTotal>100</SalesTotal>
              </m:GetSalesTax>
          </SOAP:Body>
      </SOAP:Envelope>

現在,已經準備好客戶請求文件,可以送往服務端瞭。髮送請求很簡單,可以跟瀏覽器錶單一樣,用HTTP  post方式。瀏覽器可以曏服務端髮送複雜的錶單,.NET可以曏服務器髮送VB代碼,但我使用XMLHTTP(IE 5以上版本纔能用)。

假設strEnvelope含有XML文件格式的請求,髮送格式如下:
      Dim objHTTP As New MSXML.XMLHTTPRequest
      Dim strEnvelope As String

      '設定髮往本地服務器
      objHTTP.open "post", "http://localhost/soap/soap.asp"

      '設定標準SOAP/ XML文件頭格式
      objHTTP.setRequestHeader "Content-Type", "text/xml"

      '設置呼叫函數請求
      objHTTP.setRequestHeader "SOAPMethodName", _
          "urn:myserver/soap:TaxCalc#GetSalesTax"

      '呼叫SOAP
      objHTTP.send strEnvelope

      '取得返迴值
      strReturn = objHTTP.responseBody

至此,客戶端完成瞭曏服務端髮送請求的過程。現在迴到服務端,看看服務端如何偵聽客戶請求併作齣響應。

服務端
服務端要能夠接收客戶髮齣的HTTP請求,在本地服務器(http://localhost/soap.asp)接收到客戶請求時作齣迴應。因此服務端要能夠解析客戶端髮齣的XML格式(SOAP封裝)的請求,取齣調用的函數名和蔘數。

服務端文件是soap.asp,牠接收客戶請求的做法是:
      Set objReq = Server.CreateObject("Microsoft.XMLDOM")
      objReq.Load Request

然後用XSL樣式從封裝的XML文件中取齣蔘數:
      strQuery = "SOAP:Envelope/SOAP:Body/m:GetSalesTax/SalesTotal"
      varSalesTotal = objReq.SelectSingleNode(strQuery).Text

根據蔘數計祘稅款:
      varSalesTax = varSalesTotal * 0.04

在將結果返迴給客戶之前,要按SOAP標準做格式化封裝。過程與客戶端類似,隻是把"IN"蔘數改換爲"OUT"蔘數,併將函數標記名標爲迴應:
      <SOAP:Envelope xmlns:SOAP="urn:schemas-xmlsoap-org:soap.v1">
         <SOAP:Header></SOAP:Header>
         <SOAP:Body>
            <m:GetSalesTaxResponse xmlns:m="urn:myserver/soap:TaxCalc">
               <SalesTax>4</SalesTax>
            </m:GetSalesTaxResponse>
         </SOAP:Body>
      </SOAP:Envelope>

可以用字符串方式構造這箇迴應文件,也可以創建一箇DOM對象,增加一箇節點。
文件返迴給客戶後,客戶經過解碼就能得到結果:
      Dim objReturn As New MSXML.DomDocument
      objReturn.LoadXML strReturn
      strQuery = _
        "SOAP:Envelope/SOAP:Body/m:GetSalesTaxResponse/SalesTax"
      dblTax = objReturn.SelectSingleNode(strQuery).Text

這樣就完成瞭一箇簡單的SOAP服務應用。雖然Visual Studio 7掩蓋瞭內在的SOAP協議,但我希望本文有助於理解SOAP的操作過程。

下麵是客戶端VB代碼:
      VB Client Code
      Sub Main()
        Dim objHTTP As New MSXML.XMLHTTPRequest
        Dim strEnvelope As String
        Dim strReturn As String
        Dim objReturn As New MSXML.DOMDocument
        Dim dblTax As Double
        Dim strQuery As String
       
        '創建SOAP封裝
        strEnvelope = _
          "<soap:envelope xmlns:soap=""urn:schemas-xmlsoap-org:soap.v1"">" & _
          "<soap:header></soap:header>" & _
          "<soap:body>" & _
          "<m:getsalestax xmlns:m=""urn:myserver/soap:TaxCalculator"">" & _
          "<salestotal>100</salestotal>" & _
          "</m:getsalestax>" & _
          "</soap:body>" & _
          "</soap:envelope>"
       
        '設定髮往本地服務器
        objHTTP.open "post", "http://localhost/soap.asp", False
       
        '設定標準SOAP/ XML格式
        objHTTP.setRequestHeader "Content-Type", "text/xml"
       
        '設置調用函數頭
        objHTTP.setRequestHeader "SOAPMethodName", _
          "urn:myserver/soap:TaxCalculator#GetSalesTax"
       
        'SOAP呼叫
        objHTTP.send strEnvelope
       
        '取齣返迴信封
        strReturn = objHTTP.responseText
       
        '加載到DOM
        objReturn.loadXML strReturn
       
        '查詢返迴值
        strQuery = _
          "SOAP:Envelope/SOAP:Body/m:GetSalesTaxResponse/SalesTax"
        dblTax = objReturn.selectSingleNode(strQuery).Text
       
        Debug.Print dblTax
      End Sub
    
    
     下麵是服務端ASP代碼(文件名soap.asp,存放在本地服務器根目録下):
      <%
      Set objReq = Server.CreateObject("Microsoft.XMLDOM")

      '加載請求到XML DOM
      objReq.Load Request

      '按照輸入蔘數查詢
      strQuery = "SOAP:Envelope/SOAP:Body/m:GetSalesTax/SalesTotal"
      varSalesTotal = objReq.SelectSingleNode(strQuery).Text

      '計祘
      varSalesTax = varSalesTotal * 0.04

      '準備返迴信封
      strTmp = _
      "<soap:envelope xmlns:soap=""urn:schemas-xmlsoap-org:soap.v1"">" & _
      "<soap:header></soap:header>" & _
      "<soap:body>" & _
      "<m:getsalestaxresponse xmlns:m=""urn:myserver/soap:TaxCalc"">" & _
      "<salestax>" & varSalesTax & "</salestax>" & _
      "</m:getsalestaxresponse>" & _
      "</soap:body>" & _
      "</soap:envelope>"

      '迴寫結果文件
      Response.Write strTmp
      %>

分享